Przyklejone tło - 2006-11-15
Podczas modelowania obiektu, nie zaczynaj od ustawień sceny, stwórz sobie jakieś tło i dopiero jak będziesz miał obiekt gotowy to zajmij się otoczeniem
wiecej >>

Szukaj: 
Logowanie
Login
Hasło   
Pamiętaj mnie na tej stronie
 Zarejestruj się...




Najnowsza grafika
maxmoon
2012-04-24


Najnowsza tapeta
Nunas
2011-09-15
Krzywe Beziera

Dla kogo jest przeznaczony ten toturial

Denerwująca regułka, ale postaram się odpowiedzieć na to pytanie.
Tutorial ten przeznaczony jest w zasadzie dla każdego, kto chciałby zobaczyć działanie programu KrzyweBeziera i dowiedzieć się czegoś odnośnie Lathe.

Co znajdziesz w tym toturialu:

  • Podstawowe ustawienia środowiska
  • Trochę o teksturach i materiałach
  • Informacje odnośnie KrzywychBeziera (programie)
  • Informacje odnośnie Lathe

    No to luu panienki czyli zaczynamy:


    Krok 1: Założenia podstawowe.

    Napiszę to, choć wydaje mi się to zbędne i trochę poniżające czytających.
    Na początku należy stworzyć nową scenę (dla tych co używają programu pod Windows: File -> New File a dla tych co pracują pod linuxem proponuję: vi dzbanek.pov ).

    Do naszej sceny dołączymy czyli includniemy plik z pre-definiowanymi kolorami. Do tego celu użyjemy instrukcji include
      
      #include "colors.inc"
      
    

    Jednym z podstawowych elementów naszej sceny (każdej sceny jest kamera)
      
      camera {
        location  <0.0, 5.5, -12.0>
        look_at   <0.0, 1.0,  0.0>
        rotate y*45
        angle 40
      }
      
    

    Dokładne informacje odnośnie ustawień kamery i świata povray zostały opisane w toturialu "Praca z programem POVRay"

    Jako, że naszym celem w tym Toturialu jest skupienie się na lathe i programiku wspomagającym KrzyweBeziera podam co jeszcze wpisujemy do naszej sceny bez zbytniego rozpisywania się o poszczególnych elementach.

    Dodajemy niebo.
      
      sky_sphere {
        pigment {
          gradient y
          color_map {
            [0.0 rgb <0.6,0.7,1.0>]
            [0.7 rgb <0.0,0.1,0.8>]
          }
        }
      }
      
    

    I dwa białe światła.
      
      light_source { <0, 0, 0> color rgb <1, 1, 1>  translate <-30, 30, 0>}
      light_source { <0, 0, 0> color rgb <1, 1, 1>  translate <0, 30, -30>}
      
    

    Dodatkowo wstawiamy jeszcze coś w rodzaju narożnika pokojowego :-)
      
      union
      {
             box{<-10,-10,-10>,<10,0,10>}
             box{<-10,0,9.8>,<10,10,10>}
             box{<9.8,0,9.8>,<10,10,-10>}
             pigment { cells }
      }
      
    

    Po zrenderowaniu nasza scena powinna wyglądać tak.

    Krok 2: Praca z programem KrzyweBeziera


    Teraz zacznijmy prace nad naszym prostym dzbankiem

    Uruchamiamy program KrzyweBeziera. (Program można poprać z działu download). Po uruchomieniu programu powinien on wyglądać tak:,


    Przed tworzeniem krzywej pierwej należy określić początek układu współrzędnego. W tym celu należy nacisnąć przycisk osi (klawisz F11)



    Po wybraniu tego przycisku pojawi nam się z boku panel do ustawiania punktu <0,0> i punktu <1,1>.



    Przy wybranym "ustaw punkt <0,0>. Klikamy w polu edycyjnym gdzieś w lewym dolnym rogu. Następnie zaznaczamy "Ustaw punkt <1,1> i klikamy w polu edycyjnym na prawo od powstałej osi. Powinniśmy uzyskać taki efekt.



    Dobrze teraz kiedy już zdeklarowaliśmy osie i punkt <1,1> przechodzimy do edycji naszej Krzywej. W tym celu klikamy przycisk Krzywych (albo wybieramy klawiatury kombinacje klawiszy (CRTL + 1)




    Aby móc zacząć tworzenie krzywej, która będzie reprezentowała nam profil dzbanka, należy kliknąć przycisk "Utwórz krzywą"



    Jeżeli wszystko poszło dobrze, pod przyciskiem powinniśmy mieć podświetloną nazwę nowoutworzonej krzywej. Teraz w polu edycyjnym (to duże szare po środku), poprzez dwukliknięcie dodajemy punkty do krzywej.

    Nasz profil dzbanka będzie składał się z szeregu pojedynczych krzywych Bezeira.
    Pojedyncza Krzywa Beziera składa się z czterech punktów. Punktu początkowego (kolor zielony) dwóch punktów pomocniczych (kolor czerwony) i punktu końcowego. Podczas dodawania punktów do naszej krzywej będzie dodawali tylko punkty początku i końca. Punkty pomocnicze będą dodawane automatycznie.

    Teraz próbujemy narysować odpowiedni profil, który powinien mniej więcej tak wyglądać.



    To jest dobre miejsce, aby wspomnieć o skrótach klawiaturowych i operacjach myszką.

    Operacje myszką:
  • Po kliknięciu lewym przyciskiem na punkt możemy go przesuwać.
  • Po kliknięciu środkowym przyciskiem na punkt (początku albo końca) możemy przesuwać ten punkt wraz z dziećmi (punktami czerwonymi)
  • Po kliknięciu prawego przycisku myszy możemy przesuwać całą krzywą
  • CRTL+1 - edytowanie krzywej (dodawanie nowych punktów na końcu krzywej)
  • CRTL+2 - Dodawanie nowego punktu w środku krzywej (najpierw wybieramy punkt po którym chcemy dodać nowy punkt, a później miejsce w którym chcemy wstawić ten punkt)
  • CRTL+3 - usuwanie punktu (istnieje możliwość usunięcia tylko punktów (początku lub końca)
  • CTRL+4 - Przyciąganie punku do osi y czyli x=0

    Dobrze, ale przejdźmy do rzeczy kiedy mamy już profil przydało by się wygenerować obiekt POVRay;owy W tym celu należy kliknąć przycisk POVRay


    Pojawi nam się panel z ustawieniami exportu do POVRay'a i teraz powinniśmy móc zaznaczyć w polu edycyjnym kodu povraya i nacisnąć przycisk do schowka, albo z poziomu edycji Krzywej Bezieraz wybieramy z klawiatury kombinacje CRTL+SHIFT+Z co spowoduje skopiowanie danej krzywej Bezeira do schowka jako "obiekt" LATHE

    I przechowywany w schowku tekst wklejamy w POVRay'u (CRTL + V)

      
      lathe {
      bezier_spline
      28
      <0,0>,<0.228,0>,<0.728,0>,<0.898,0>
      <0.898,0>,<1.033,0.051>,<1.033,0.179>,<0.898,0.247>
      <0.898,0.247>,<0.754,0.290>,<0.627,0.307>,<0.525,0.316>
      <0.525,0.316>,<1.245,1.145>,<1.355,2.068>,<0.881,3.521>
      <0.881,3.521>,<0.855,3.623>,<0.805,3.615>,<0.796,3.529>
      <0.796,3.529>,<1.245,2.085>,<1.1949,1.2131>,<0.4491,0.316>
      <0.449,0.316>,<0.372,0.179>,<0.194,0.188>,<0,0.196>
      pigment { color Red }
      }
      
    



    Teraz słówko o LATHE
    Otóż jak w dokumentacji napisali:
    W prawdziwym świecie słowo lathe odnosi się do procesu tworzenie obiektu opartego na jakimś wzorcu obróconym po okręgu. Rezultatem może być gładka, ładnie wyglądająca figura obrotowa taka jak noga od stołu, czy też dzbanki gliniane robione na kole garncarskim.
    A mówiąc prostymi słowy Lathe jest to obiekt utworzony poprzez obrót naszej krzywej wokół osi Y. Ważną informacją jest to że nasza krzywa nie może mieć żadnej współrzędnej X mniejszej od zera.

    Składnia Lathe z definicji :-)

      
      lathe { 
      bezier_spline // deklaracja rodzaju krzywych którymi jest repezentowany nasz profil
      28 // ilość punktów jakie zostały użyte w tym profilu
      // poszczególne punkty
      pigment { color Red } // kolor obiektu
      }
      
    
    Po wyrenderowaniu nasza scen powinna wyglądać tak:



    Teraz tylko upiększymy czyli nadamy jaką teksturkę. Do tego celu użyjemy gotowych pre-definiowanych tektur szkła dostępnych w pliku glass.inc.

    Zamias
      
      include "color.inc"
      
    
    Wstawiamy
      
      include "glass.inc"
      
    

    I tworzymy nowy materiał
      
      #declare M_dzban=material
      {                        
              texture {
                      pigment { color rgbft <1,0,0,.5, .5>}
                      finish  { F_Glass1  }
                      }
              interior { I_Glass1 }
      }
      
    

    I wstawiamy do naszego dzbanka :-)
    Kompletny kod naszej sceny powinien wyglądać tak.

      
      #include "glass.inc"
      global_settings {
        assumed_gamma 1.0
      }
      camera {
        location  <0.0, 5.5, -12.0>
        look_at   <0.0, 1.0,  0.0>
        rotate y*45
        angle 40
      }
      sky_sphere {
        pigment {
          gradient y
          color_map {
            [0.0 rgb <0.6,0.7,1.0>]
            [0.7 rgb <0.0,0.1,0.8>]
          }
        }
      }
      light_source { <0, 0, 0> color rgb <1, 1, 1>  translate <-30, 30, 0>}
      light_source { <0, 0, 0> color rgb <1, 1, 1>  translate <0, 30, -30>}
      union
      {
             box{<-10,-10,-10>,<10,0,10>}
             box{<-10,0,9.8>,<10,10,10>}
             box{<9.8,0,9.8>,<10,10,-10>}
             pigment { cells }
      }
      
      
      #declare M_dzban=material
      {                        
              texture {
                      pigment { color rgbft <1,0,0,.5, .5>}
                      finish  { F_Glass1  }
                      }
              interior { I_Glass1 }
      }
      
      lathe {
      bezier_spline
              28
             <0,0>,<0.228,0>,<0.728,0>,<0.898,0>
            <0.898,0>,<1.033,0.051>,<1.033,0.179>,<0.898,0.247>
            <0.898,0.247>,<0.754,0.290>,<0.627,0.307>,<0.525,0.316>
            <0.525,0.316>,<1.245,1.145>,<1.355,2.068>,<0.881,3.521>
            <0.881,3.521>,<0.855,3.623>,<0.805,3.615>,<0.796,3.529>
            <0.796,3.529>,<1.245,2.085>,<1.1949,1.2131>,<0.4491,0.316>
            <0.449,0.316>,<0.372,0.179>,<0.194,0.188>,<0,0.196>
              material { M_dzban }
      }
      
    


    A wyrenderwoana scena powinna wyglądać tak:



  • Plik źródłowy
  • Plik z krzywą
  • © druidy.pl

    Korzystając z witryny bez zmiany ustawień przeglądarki wyrażasz zgodę na użycie plików cookies. W każdej chwili możesz swobodnie zmienić ustawienia przeglądarki decydujące o ich zapisywaniu.